Ljung-BoxのQ統計量, Breusch-Pagan test, Breusch-Godfrey　Test

OPTIONS DOUBLE;
FREQ M;
SMPL 1950:2 1990:12;
READ(FILE='mishkin.asc')YEAR MONTH PAI1 PAI3 TB1 TB3 CPI;
SMPL 1950:3 1990:12;
PAI=((CPI/CPI(-1))**12-1)*100;
R=TB1-PAI;
SMPL 1953:1 1971:7;
? Rに系列相関があるかどうかをLjung-BoxのQ統計量で診断
BJIDENT R;
? REGOPTは最小二乗法でのオプションを指定する
? LMLAGSでは系列相関のBreusch-Godfrey testで12期のラグを示す
? BPLISTでは定数項とTB1を用いた不均一分散のBreusch-Pagan testを行う
REGOPT(LMLAGS=12,PVPRINT,BPLIST=(C TB1));
? 誤差項の不均一分散に頑健な、推定量の分散の推定量と
? それを用いた仮説テスト
OLSQ(HCTYPE=0,ROBUSTSE) PAI C TB1;
SET TRATIO=(@COEF(2)-1)/@SES(2);
SET DFT=@NOB-@NCOEF;
? 分布にt分布と正規分布を仮定してp値を計算してみる。
CDF(T,DF=DFT,TWOTAIL) TRATIO;
CDF(NORMAL,TWOTAIL) TRATIO;
?
? Breusch-Godfrey　Test
? 残差で必要とされる初期値を0とおいてnR^2を計算する方法
TITLE 'Breusch-Godfrey Test (1). (Use period 1952/1-1971/7)';
RESID=@res;
SMPL 52:1 52:12;
TITLE ' We set e_0=e_{-1}=...e_{-11}=0 (1952/1-1952/12)';
RESID=0;
SMPL 53:1 71:7;
OLSQ(SILENT) RESID C TB1 RESID(-1)-RESID(-12);
SET W1=@NOB*@RSQ;
CDF(CHISQ,DF=12) W1;
? Breusch-Godfrey　Test
? 初期値に0を設定するのではなく、期間を短くしてnR^2を計算
? する方法
TITLE 'Breusch-Godfrey Test (2). (Use period 1953/1-1971/7)';
SMPL 54:1 71:7;
OLSQ(SILENT) RESID C TB1 RESID(-1)-RESID(-12);
TITLE 'Use nR^2';
SET W2=@NOB*@RSQ;
CDF(CHISQ,DF=12) W2;
? Breusch-Godfrey　Test
? TSPのREGOPT(LMLAGS=12)で使われる統計量の計算は
? nR^2ではなく以下のように p x Fである。
TITLE 'Use p x F';
SET SSRU=@SSR;SET DFU=@NOB-@NCOEF;
OLSQ(SILENT) RESID C TB1;
SET SSRR=@SSR;
SET FSTAT=((SSRR-SSRU)/12)/(SSRU/DFU);
SET W3=12*FSTAT;
CDF(CHISQ,DF=12) W3;